5 Things I Like About CoffeeScript

The World of JavaScript

This should look familiar...

var toCamel = function (str) {
  return str.replace(/(\_[a-z])/g, function (val) {
    return val.toUpperCase().replace('_', '');
  });
};

console.log(toCamel("my_cased_variable"));

The World of CoffeeScript

... and this shouldn't look too different

toCamel = (str) ->
  str.replace /(\_[a-z])/g, (val) ->
    val.toUpperCase().replace '_', ''

console.log toCamel "my_cased_variable"

Overview

CoffeeScript.org
CoffeeScript is JavaScript
... with the minimal useful boilerplating
Works in Node.js or browser

1. Syntax

Borrows from Ruby (e.g., string interpolation) and Python (e.g., whitespace, comprehensions).

myArray   = [ "optional"
              "commas" ]
myObject  =
  foo:    "the foo property"
  bar:
    baz1: "nested"
    baz2: "properties"

myString  = """
  Yeah, CoffeeScript has multi-line
  (heredoc-style) strings!!!
"""

2. Functions

Useful enhancements include defaults (bar = "hi") and splats (...args).

myFn = (foo, bar="hi", args...) ->
  console.log "foo: #{foo}, bar: #{bar}, " +
              "args: #{args.join(', ')}"

myFn(23, null, "boo", 42) # Var-args
myFn([12, 22, 34]...)     # Expand

3. Classes

Follows the "classical inheritance" pattern with helpers: shortcuts (@), fat arrows (=>), and superclass (super).

class MyClass
  constructor: (@foo, @bar) ->
  @staticMethod: -> console.log "static!"
  instanceMethod: => console.log "instance! (#{@foo})"

myObj = new MyClass(42, 23)
MyClass.staticMethod()              # Static
myObj.instanceMethod()              # Instance
myObj.instanceMethod.call this, []  # Bound

4. Existential Operator

An elegant way to avoid TypeError's and replace:

var myObj = {foo: {bar: 12}};
if (myObj && myObj.foo && myObj.foo.bar)
  console.log(myObj.foo.bar);

... with:

myObj = foo: bar: 12
console.log myObj?.foo?.bar
console.log myObj?.nope?.noHow?().nowhere

5. Loops, Comprehensions

Works for arrays and objects.

myArr = ["one", "two", "three"]
comp = ("**#{x}**" for x in myArr)
console.log comp

myObj = {one: 1, two: 2, three: 3}
comp = ([k, v+1] for own k, v of myObj)
console.log comp

Issues / Gotchas

CoffeeScript is JavaScript
Pre-compilation: JavaScript or CoffeeScript?
Debugging
Static analysis tools
Language choices: significant whitespace, no semicolons, optional function parentheses

Thanks!

slides: bit.ly/nodedc-coffeescript

@ryan_roemer ryan@loose-bits.com

SpanishDict.com is hiring!